user: implement mlibc as the libc, finally.

It's finally done..

Signed-off-by: kaguya <vpshinomiya@protonmail.com>

user/include/mlibc/options/internal/aarch64/fenv.S

@@ -0,0 +1,69 @@
+# The functions below are taken from musl.
+.global fegetround
+.type fegetround,%function
+fegetround:
+	mrs x0, fpcr
+	and w0, w0, #0xc00000
+	ret
+
+.global __fesetround
+.hidden __fesetround
+.type __fesetround,%function
+__fesetround:
+	mrs x1, fpcr
+	bic w1, w1, #0xc00000
+	orr w1, w1, w0
+	msr fpcr, x1
+	mov w0, #0
+	ret
+
+.global fetestexcept
+.type fetestexcept,%function
+fetestexcept:
+	and w0, w0, #0x1f
+	mrs x1, fpsr
+	and w0, w0, w1
+	ret
+
+.global feclearexcept
+.type feclearexcept,%function
+feclearexcept:
+	and w0, w0, #0x1f
+	mrs x1, fpsr
+	bic w1, w1, w0
+	msr fpsr, x1
+	mov w0, #0
+	ret
+
+.global feraiseexcept
+.type feraiseexcept,%function
+feraiseexcept:
+	and w0, w0, #0x1f
+	mrs x1, fpsr
+	orr w1, w1, w0
+	msr fpsr, x1
+	mov w0, #0
+	ret
+
+.global fegetenv
+.type fegetenv,%function
+fegetenv:
+	mrs x1, fpcr
+	mrs x2, fpsr
+	stp w1, w2, [x0]
+	mov w0, #0
+	ret
+
+// TODO preserve some bits
+.global fesetenv
+.type fesetenv,%function
+fesetenv:
+	mov x1, #0
+	mov x2, #0
+	cmn x0, #1
+	b.eq 1f
+	ldp w1, w2, [x0]
+1:	msr fpcr, x1
+	msr fpsr, x2
+	mov w0, #0
+	ret

user/include/mlibc/options/internal/aarch64/setjmp.S

@@ -0,0 +1,67 @@
+// vim: ft=arm64asm
+
+.extern __sigsetjmp
+
+.type __setjmp, "function"
+__setjmp:
+	stp x19, x20, [x0, #0]
+	stp x21, x22, [x0, #16]
+	stp x23, x24, [x0, #32]
+	stp x25, x26, [x0, #48]
+	stp x27, x28, [x0, #64]
+	stp x29, x30, [x0, #80]
+	mov x4, sp
+	str x4, [x0, #96]
+
+	stp d8, d9, [x0, #112]
+	stp d10, d11, [x0, #128]
+	stp d12, d13, [x0, #144]
+	stp d14, d15, [x0, #160]
+
+	cbnz x2, 1f
+
+	mov x0, xzr
+	ret
+1:
+	b __sigsetjmp
+
+.global setjmp
+.type setjmp, "function"
+.global _setjmp
+.type _setjmp, "function"
+setjmp:
+_setjmp:
+	mov x2, xzr
+	b __setjmp
+
+.global sigsetjmp
+.type sigsetjmp, "function"
+sigsetjmp:
+	mov x2, #1
+	b __setjmp
+
+.global longjmp
+.type longjmp, "function"
+.global _longjmp
+.type _longjmp, "function"
+longjmp:
+_longjmp:
+	ldp x19, x20, [x0, #0]
+	ldp x21, x22, [x0, #16]
+	ldp x23, x24, [x0, #32]
+	ldp x25, x26, [x0, #48]
+	ldp x27, x28, [x0, #64]
+	ldp x29, x30, [x0, #80]
+	ldr x4, [x0, #96]
+	mov sp, x4
+
+	ldp d8, d9, [x0, #112]
+	ldp d10, d11, [x0, #128]
+	ldp d12, d13, [x0, #144]
+	ldp d14, d15, [x0, #160]
+
+	cmp w1, 0
+	csinc w0, w1, wzr, ne
+	br x30
+.section .note.GNU-stack,"",%progbits
+